ソースは以下の通り。
1: #!/usr/local/bin/perl
2:
3: # $Id: image-2.cgi,v 1.4 2004/07/21 17:42:09 68user Exp $
4:
5: use strict;
6: use GD;
7:
8: my $PI = 3.141592;
9:
10: my $width = 500; # 画像の幅
11: my $height = 200; # 画像の高さ
12:
13: my $im = new GD::Image($width, $height);
14:
15: my $black = $im->colorAllocate( 0, 0, 0);
16: my $str_color = $im->colorAllocate( 0, 0, 0);
17: my $str_shadow_color = $im->colorAllocate(190, 190, 190);
18: my $bgcolor = $im->colorAllocate(255, 255, 255);
19: my $circle_color = $im->colorAllocate(230, 110, 110);
20:
21: # インタレースを ON
22: $im->interlaced('true');
23:
24: # 背景色として塗りつぶし四角を描く
25: $im->filledRectangle(0, 0, $width-1, $height-1, $bgcolor);
26:
27: # 外枠を描画
28: $im->rectangle(0, 0, $width-1, $height-1, $black);
29:
30: # 内側の丸を書いて、外側の丸を書いて、内側と外側の丸の間を塗りつぶす
31: $im->arc($width/2, $height/2, 160, 160, 0, 360, $circle_color);
32: $im->arc($width/2, $height/2, 220, 220, 0, 360, $circle_color);
33: $im->fill($width/2+81, $height/2, $circle_color);
34:
35: my $fontsize_min = 10; # 初期フォントサイズ
36: my $fontsize_max = 50; # 最大フォントサイズ
37: my $fontsize_delta = 7; # フォントサイズ増分
38:
39: my $str_x = 0; # X 座標
40: my $str_y = $fontsize_min; # Y 座標
41: my $angle = 0; # 回転角度 (ラジアン)
42:
43: my $font_file ='/usr/X11R6/lib/X11/fonts/TrueType/sazanami-gothic.ttf';
44: my @strs =
45: ('寿限無寿限無五劫のすりきれ海砂利水魚の水行末雲来末風来末食う寝るところに住むところやぶら小路のぶら小路',
46: '祇園精舎の鐘の声 諸行無常の響きあり 沙羅双樹の花の色 盛者必衰の理をあらわす おごれる人も久しからず',
47: '春はあけぼの。やうやう白くなりゆく山ぎは、少し明りて、紫だちたる雲の、細くたなびきたる。夏は、夜。',
48: '色は匂へど 散りぬるを 我がよ誰そ 常ならむ 有為の奥山 今日越えて あさき夢見し ゑひもせず',
49: );
50: my $str = $strs[int(rand(scalar(@strs)))];
51:
52: for ( my $size=$fontsize_min ; $size<=$fontsize_max ; $size += $fontsize_delta ){
53:
54: # 文字の影を描画
55: $im->stringFT($str_shadow_color, # 色
56: $font_file, $size, # フォント・フォントサイズ
57: $angle*($PI/180), # 回転角度
58: $str_x+2, $str_y+2, # X・Y 座標
59: $str); # 表示文字列
60:
61: # 文字を描画
62: $im->stringFT($str_color, # 色
63: $font_file, $size, # フォント・フォントサイズ
64: $angle*($PI/180), # 回転角度
65: $str_x, $str_y, # X・Y 座標
66: $str); # 表示文字列
67:
68: $str_y += $size+14;
69: $angle -= 2;
70: }
71:
72: binmode STDOUT;
73: print "Content-type: image/png\n\n";
74: print $im->png;
75:
76: exit 0;
解説するまでもないんですが、いちおう軽く触れておきましょう。
6: use GD;
まずは GD モジュールをインポートします。
10: my $width = 500; # 画像の幅 11: my $height = 200; # 画像の高さ
13: my $im = new GD::Image($width, $height);画像の幅と高さを決めて、new GD::Image で GD のオブジェクトを生成します。 このオブジェクトは仮想的なキャンパスのようなもので、 このオブジェクトの上に線や文字を書いていくわけです。
15: my $black = $im->colorAllocate( 0, 0, 0); 16: my $str_color = $im->colorAllocate( 0, 0, 0); 17: my $str_shadow_color = $im->colorAllocate(190, 190, 190); 18: my $bgcolor = $im->colorAllocate(255, 255, 255); 19: my $circle_color = $im->colorAllocate(230, 110, 110);色を確保します。色は RGB で 0〜255 の範囲で指定します。
22: $im->interlaced('true');
interlaced('true') でインタレースモードにできます。
このモードにすることで「最初は解像度が低く、時間が経つごとに解像度があがっていく」
というおなじみの機能を使うことができます。
PNG・GIF の場合は「インタレース PNG・インタレース GIF」と呼び、
JPEG の場合は「プログレッシブ JPEG」と呼ぶようです。
25: $im->filledRectangle(0, 0, $width-1, $height-1, $bgcolor);filledRectangle は塗りつぶした四角を描きます。つまり、 画像の全領域を塗りつぶすことで、背景色を設定する効果があるわけです。
GD の座標系は左上が (0,0)、右下が (x-1, y-1) となります。
28: $im->rectangle(0, 0, $width-1, $height-1, $black);rectangle は四角を描きます。filledRectangle と違い、 四角の内側は塗りつぶしません。
31: $im->arc($width/2, $height/2, 160, 160, 0, 360, $circle_color); 32: $im->arc($width/2, $height/2, 220, 220, 0, 360, $circle_color); 33: $im->fill($width/2+81, $height/2, $circle_color);arc は円弧を描くメソッド、 fill は指定した点を塗りつぶすメソッドです。 小さな赤い丸と大きな赤い丸を書いて、その中間を塗りつぶすことで、 太い丸を書いているわけです。
ここから文字を描画するわけですが、まず使用するフォントと表示する文字を決めます。 まずフォントですが、
43: my $font_file ='/usr/X11R6/lib/X11/fonts/TrueType/sazanami-gothic.ttf';と指定しています。これは「さざなみフォント」と呼ばれるもので、 2004年6月にリリースされたものですから、 みなさんのお手元のマシンにはインストールされていないかもしれません。 その場合は、さざなみフォント配布サイトから
- sazanami-gothic.ttf
- sazanami-mincho.ttf
Windows や Solaris であればそれなりのフォントが標準で用意されています。 フリーの UNIX 系 OS でもいくつか TrueType フォントがあります。 拡張子が ttf で、ファイルサイズが数 MB あるファイルがあれば、 おそらくそれは日本語の TrueType フォントでしょう。
44: my @strs =
45: ('寿限無寿限無五劫のすりきれ海砂利水魚の水行末雲来末風来末食う寝るところに住むところやぶら小路のぶら小路',
46: '祇園精舎の鐘の声 諸行無常の響きあり 沙羅双樹の花の色 盛者必衰の理をあらわす おごれる人も久しからず',
47: '春はあけぼの。やうやう白くなりゆく山ぎは、少し明りて、紫だちたる雲の、細くたなびきたる。夏は、夜。',
48: '色は匂へど 散りぬるを 我がよ誰そ 常ならむ 有為の奥山 今日越えて あさき夢見し ゑひもせず',
49: );
50: my $str = $strs[int(rand(scalar(@strs)))];
表示する文字列はいくつかのパターンを用意しておき、ランダムに決定しています。
62: $im->stringFT($str_color, # 色 63: $font_file, $size, # フォント・フォントサイズ 64: $angle*($PI/180), # 回転角度 65: $str_x, $str_y, # X・Y 座標 66: $str); # 表示文字列stringFT メソッドを使って文字列を表示します。
以前は stringTTF メソッドでしたが、今は名前が変わって stringFT になりました。
ただし stringTTF も従来どおり使えます。
72: binmode STDOUT; 73: print "Content-type: image/png\n\n"; 74: print $im->png;最後に png メソッドを使って画像を表示しています。
最初のサンプルプログラムでは「この例では Windows であっても実は binmode は不要」と書きましたが、 今回は Windows ならば必ず binmode が必要です。binmode を使用しなかった場合、 GD が生成する画像データ内にたまたま 0x0A があったとして、 それを標準出力 (STDOUT) に出力する際に 0x0A が 0x0D 0x0A に変換されてしまい、 本来の画像データが化けてしまうことになるからです。
サンプルプログラムでは文字を傾けたり、フォントサイズを少しずつ大きくしたりしていますが、 そんな細かいところはどうでもいいので、GD モジュールを使うにはどうしたらよいか、 という雰囲気をつかんでください。